Comparing .NET Compiled CIL of Equivalent C# Switch Expressions

Comparison Details:

Compiler and Framework Details

Operating System: Windows 10
Compiler: Rosyln Compiler
Framework Version: .NET Core 3.1.1
Source Code Editor: LinqPad 6

Review Description

This content reviews the .NET CIL (a.k.a. Common Intermediate Language) code compiled from the 3 C# code equivalents listed below.

See the code comments section for more background on why this code was created.

Code snippets for executing conditional expressions based on a range of inequalities for value assignment.

Code Snippet 1 of 3: if Statements
Code Snippet 2 of 3: C# 8 Switch Expression
Code Snippet 3 of 3: Nested Ternary

Code Snippet 1 of 3: if Statements

Return to List of Code Snippets

C# Code

Simple variable assignments within traditional if / else blocks using conditional expressions.

var num = 15;
var lower = 10;
var upper = 20;
var result = "";

if(num < lower) {
  result = $"less than {lower}";
} else if (num > upper) {
  result = $"greater than {upper}";
} else {
  result = $"between {lower} and {upper}";
}

.NET Intermediate Language

CIL generated from traditional if statements appears to as compact and efficient as CIL for the new C# switch expression in code snippet #2.

IL_0000:  nop         
IL_0001:  ldc.i4.s    0F 
IL_0003:  stloc.0     
IL_0004:  ldc.i4.s    0A 
IL_0006:  stloc.1     
IL_0007:  ldc.i4.s    14 
IL_0009:  stloc.2     
IL_000A:  ldstr       ""
IL_000F:  stloc.3     
IL_0010:  ldloc.0     
IL_0011:  ldloc.1     
IL_0012:  clt         
IL_0014:  stloc.s     04 
IL_0016:  ldloc.s     04 
IL_0018:  brfalse.s   IL_002F
IL_001A:  nop         
IL_001B:  ldstr       "less than {0}"
IL_0020:  ldloc.1     
IL_0021:  box         System.Int32
IL_0026:  call        System.String.Format
IL_002B:  stloc.3     
IL_002C:  nop         
IL_002D:  br.s        IL_0067
IL_002F:  ldloc.0     
IL_0030:  ldloc.2     
IL_0031:  cgt         
IL_0033:  stloc.s     05 
IL_0035:  ldloc.s     05 
IL_0037:  brfalse.s   IL_004E
IL_0039:  nop         
IL_003A:  ldstr       "greater than {0}"
IL_003F:  ldloc.2     
IL_0040:  box         System.Int32
IL_0045:  call        System.String.Format
IL_004A:  stloc.3     
IL_004B:  nop         
IL_004C:  br.s        IL_0067
IL_004E:  nop         
IL_004F:  ldstr       "between {0} and {1}"
IL_0054:  ldloc.1     
IL_0055:  box         System.Int32
IL_005A:  ldloc.2     
IL_005B:  box         System.Int32
IL_0060:  call        System.String.Format
IL_0065:  stloc.3     
IL_0066:  nop         
IL_0067:  ret

Code Snippet 2 of 3: C# 8 Switch Expression

Return to List of Code Snippets

C# Code

Equivalent variable assignment using the new switch expressions introduced in C #8.

var num = 15;
var lower = 10;
var upper = 20;

var x = num switch {
  _ when num < lower 
    => $"less than {lower}",
  _ when num > upper
    => $"greater than {upper}",
  _ => $"between {lower} and {upper}"
};

.NET Intermediate Language

CIL generated from the new C# switch expression appears to as compact and efficient as CIL from traditional if statements as seen in code snippet #1.

IL_0000:  nop         
IL_0001:  ldc.i4.s    0F 
IL_0003:  stloc.0     
IL_0004:  ldc.i4.s    0A 
IL_0006:  stloc.1     
IL_0007:  ldc.i4.s    14 
IL_0009:  stloc.2     
IL_000A:  ldloc.0     
IL_000B:  stloc.s     05 
IL_000D:  ldc.i4.1    
IL_000E:  brtrue.s    IL_0011
IL_0010:  nop         
IL_0011:  br.s        IL_0013
IL_0013:  ldloc.0     
IL_0014:  ldloc.1     
IL_0015:  blt.s       IL_0019
IL_0017:  br.s        IL_002D
IL_0019:  ldstr       "less than {0}"
IL_001E:  ldloc.1     
IL_001F:  box         System.Int32
IL_0024:  call        System.String.Format
IL_0029:  stloc.s     04 
IL_002B:  br.s        IL_0061
IL_002D:  ldloc.0     
IL_002E:  ldloc.2     
IL_002F:  bgt.s       IL_0033
IL_0031:  br.s        IL_0047
IL_0033:  ldstr       "greater than {0}"
IL_0038:  ldloc.2     
IL_0039:  box         System.Int32
IL_003E:  call        System.String.Format
IL_0043:  stloc.s     04 
IL_0045:  br.s        IL_0061
IL_0047:  ldstr       "between {0} and {1}"
IL_004C:  ldloc.1     
IL_004D:  box         System.Int32
IL_0052:  ldloc.2     
IL_0053:  box         System.Int32
IL_0058:  call        System.String.Format
IL_005D:  stloc.s     04 
IL_005F:  br.s        IL_0061
IL_0061:  ldc.i4.1    
IL_0062:  brtrue.s    IL_0065
IL_0064:  nop         
IL_0065:  ldloc.s     04 
IL_0067:  stloc.3     
IL_0068:  ret

Code Snippet 3 of 3: Nested Ternary

Return to List of Code Snippets

C# Code

Equivalent variable assignment using nested ternary operator expression.

var num = 15;
var lower = 10;
var upper = 20;

var x = (num < lower) 
  ? $"less than {lower}"
  : (num > upper) 
    ? $"greater than {upper}"
    : $"between {lower} and {upper}";

.NET Intermediate Language

CIL generated for assignment using nested ternary operator expressions appear to be more compact and efficient than the CIL from the equivalent variants code snippets #1 and #2.

IL_0000:  nop         
IL_0001:  ldc.i4.s    0F 
IL_0003:  stloc.0     
IL_0004:  ldc.i4.s    0A 
IL_0006:  stloc.1     
IL_0007:  ldc.i4.s    14 
IL_0009:  stloc.2     
IL_000A:  ldloc.0     
IL_000B:  ldloc.1     
IL_000C:  blt.s       IL_003C
IL_000E:  ldloc.0     
IL_000F:  ldloc.2     
IL_0010:  bgt.s       IL_002A
IL_0012:  ldstr       "between {0} and {1}"
IL_0017:  ldloc.1     
IL_0018:  box         System.Int32
IL_001D:  ldloc.2     
IL_001E:  box         System.Int32
IL_0023:  call        System.String.Format
IL_0028:  br.s        IL_003A
IL_002A:  ldstr       "greater than {0}"
IL_002F:  ldloc.2     
IL_0030:  box         System.Int32
IL_0035:  call        System.String.Format
IL_003A:  br.s        IL_004C
IL_003C:  ldstr       "less than {0}"
IL_0041:  ldloc.1     
IL_0042:  box         System.Int32
IL_0047:  call        System.String.Format
IL_004C:  stloc.3     
IL_004D:  ret

Related Codes

SoloLearn CodeBits: C# to .NET CIL Review

Simple if vs switch Statements in .NET CIL
Comparing .NET Compiled CIL of Simple if vs switch Statements
-> (Current Page) Switch Expressions vs if Statements in .NET CIL
Comparing .NET Compiled CIL of Equivalent C# Switch Expressions

Comparing .NET Compiled CIL of Equivalent C# Switch Expressions

Comparison Details:

Compiler and Framework Details

Review Description

Code Snippet 1 of 3: if Statements

C# Code

.NET Intermediate Language

Code Snippet 2 of 3: C# 8 Switch Expression

C# Code

.NET Intermediate Language

Code Snippet 3 of 3: Nested Ternary

C# Code

.NET Intermediate Language

Related Codes

SoloLearn CodeBits: C# to .NET CIL Review

SoloLearn CodeBits: C# Usage Examples of Switch Expressions

Compiler Explorer on godbolt.org

Switch Expressions vs if Statements in .NET CIL